blob: 7dc9419d44c5586298a52d9e4a9e9d954e4eff42 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Zhuoyun Wei <wzyboy@wzyboy.org>
# Contributor: Carsten Feuls <archlinux@carstenfeuls.de>
# Contributor: Gilles Hamel <hamelg at laposte dot net>
pkgname=grafana-bin
_pkgname=grafana
pkgver=6.3.0
pkgrel=1
pkgdesc="A general purpose dashboard and graph composer. It supports graphite, influxdb or opentsdb - binary version"
url="http://grafana.org"
conflicts=('grafana')
provides=('grafana')
arch=('x86_64' 'armv6h' 'armv7h' 'aarch64')
license=('Apache')
install=${_pkgname}.install
backup=("etc/${_pkgname}/${_pkgname}.ini")
source=("grafana.service")
source_x86_64=("https://dl.grafana.com/oss/release/grafana-${pkgver}.linux-amd64.tar.gz")
source_armv6h=("https://dl.grafana.com/oss/release/grafana-${pkgver}.linux-armv6.tar.gz")
source_armv7h=("https://dl.grafana.com/oss/release/grafana-${pkgver}.linux-armv7.tar.gz")
source_aarch64=("https://dl.grafana.com/oss/release/grafana-${pkgver}.linux-arm64.tar.gz")
sha256sums=('44ceb7aad648c8e46a65026109fc0327bc6e01ba7060d97d9e83a3e8ad65379c')
sha256sums_x86_64=('295a9747c7e386c4c04e744ea0093520a5914c4cf17f1e02cbae0d771d6a0107')
sha256sums_armv6h=('aaa602040334b4707aeb90afd36270a206c5a3289a14fc6c2ed02e031116d3b6')
sha256sums_armv7h=('9eb9e803db7e4ae8a444691fe500e20fa8e4b7984e9162fd4375c3928e06cec0')
sha256sums_aarch64=('ed1bc37a1348ed02404152925346609086c14e2d5188a5e97522dfcfe6e78845')
package() {
install -Dm644 "${srcdir}/grafana.service" "$pkgdir/usr/lib/systemd/system/grafana.service"
cd "${srcdir}/${_pkgname}-${pkgver}"
install -dm755 "${pkgdir}/var/lib/grafana"
install -dm755 "${pkgdir}/var/log/grafana"
install -Dm755 bin/grafana-server "$pkgdir/usr/bin/grafana-server"
install -Dm755 bin/grafana-cli "$pkgdir/usr/bin/grafana-cli"
install -Dm644 conf/sample.ini "$pkgdir/etc/${_pkgname}/${_pkgname}.ini"
install -Dm644 conf/defaults.ini "$pkgdir/usr/share/grafana/conf/defaults.ini"
cp -r public scripts tools "$pkgdir/usr/share/grafana/"
}
|