blob: 24a1ef2734cc27ea8deb5616b381424121efeaa5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
pkgbase=grails
pkgname=('grails' 'grails-docs')
pkgver=4.0.3
pkgrel=1
pkgdesc='Groovy on rails, web framework'
url='https://grails.org/'
arch=('any')
license=('Apache')
makedepends=('apache-ant' 'unzip' 'setconf' 'junit' 'java-environment')
optdepends=('groovy: the groovy programming language'
'grails-docs: documentation for grails')
options=('!emptydirs')
noextract=("${pkgname[1]}-${pkgver}.zip")
source=(${pkgname[0]}-${pkgver}.zip::https://github.com/grails/grails-core/releases/download/v${pkgver}/grails-${pkgver}.zip
${pkgname[1]}-${pkgver}.zip::https://github.com/grails/grails-doc/releases/download/v${pkgver}/grails-docs-${pkgver}.zip)
sha512sums=('4b28eccd873811c57e40188a7fef4c01a2ef00cc425eb11d51de90ca7279e283590cab167af22e0716fdca473fd67760a62007a07bb7880c18211c89bef547bf'
'0d1bdbf42f28a0efcb3ba4956fc0c37d5eac4cbed2c3a2d7a95134e8a2f324f96d4516cbe540f45bee88867dc9e78bef3b09dbd9d5b134684b17de8d6c44af33')
prepare() {
cd ${pkgbase}-${pkgver}
echo 'export GRAILS_HOME=/usr/share/grails' > "${srcdir}/${pkgbase}.profile"
setconf bin/grails APP_HOME /usr/share/grails
}
package_grails() {
depends=('java-environment' 'junit' 'bash')
cd ${pkgname}-${pkgver}
install -d "${pkgdir}/usr/share/pixmaps"
cp -r . "${pkgdir}/usr/share/${pkgname}"
install -Dm 755 bin/grails "${pkgdir}/usr/bin/grails"
install -Dm 644 media/icons/*.png -t "${pkgdir}/usr/share/pixmaps"
install -Dm 755 "${srcdir}/${pkgbase}.profile" "${pkgdir}/etc/profile.d/${pkgname}.sh"
# clean up
cd "${pkgdir}/usr/share/${pkgname}"
rm -rf doc INSTALL LICENSE README
find "${pkgdir}/usr/share" -name "*.bat" -exec rm {} \;
}
package_grails-docs() {
pkgdesc='Documentation for Grails'
install -d "${pkgdir}/usr/share/doc" "${pkgdir}/usr/share/grails"
unzip "grails-docs-${pkgver}.zip" -d "${pkgdir}/usr/share/doc/grails-${pkgver}"
ln -s "/usr/share/doc/grails-${pkgver}" "${pkgdir}/usr/share/grails/doc"
}
# vim: ts=2 sw=2 et:
|