PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81

# Maintainer: BrinkerVII <brinkervii@gmail.com>

_pkgname=grapejuice
_repository=https://gitlab.com/brinkervii/grapejuice.git
pkgname="${_pkgname}-git"
pkgver=7.20.12.r0.gca5e1b3
pkgrel=1
pkgdesc='A Wine+Roblox management tool'
arch=('x86_64')
url="${_repository}"
makedepends=('git')
depends=(
    'python'
    'python-pip'
    'python-gobject'
    'python-psutil'
    'python-packaging'
    'python-requests'
    'python-setuptools'
    'python-unidecode'
    'python-click'
    'cairo'
    'gtk3'
    'gobject-introspection'
    'desktop-file-utils'
    'xdg-utils'
    'xdg-user-dirs'
    'gtk-update-icon-cache'
    'shared-mime-info'
    'lib32-gnutls'
    'lib32-openssl'
    'lib32-libpulse'
    'mesa-utils'
)
optdepends=(
    'wine: Required to run Roblox, but left out of depends to let the user decide on custom builds'
    'xorg-xrandr: Required for PRIME systems running XOrg, where XRandR based profiling is desired'
)
provides=("${_pkgname}")
conflicts=("${_pkgname}")
license=('GPL3')
source=("${_pkgname}"::git+"${_repository}")
sha256sums=('SKIP')

_get_project_root() {
    echo "$srcdir/grapejuice"
}

pkgver() {
  cd "$_pkgname"

  _project_root=$(_get_project_root)
  export PYTHONPATH="$_project_root/src"
  
  _grapejuice_version=$(python3 -c 'from grapejuice import __version__; print(__version__)')

  ( set -o pipefail
    git describe --long --abbrev=7 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' | sed 's/^v//g' ||
    printf "%s.r%s.%s" "${_grapejuice_version} $(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
  )
}

package() {
    _python_version=$(python3 -c 'import sys; print(f"{sys.version_info.major}.{sys.version_info.minor}")')

    _project_root=$(_get_project_root)
    cd "${_project_root}" || exit 1

    export PYTHONPATH="$_project_root/src"
    python3 -m grapejuice_packaging linux_package

    _built_package_root="${_project_root}/dist/linux_package"
    cd "${_built_package_root}" || exit 1
    tar -xf *.tar.gz -C "${pkgdir}"

    _site_packages=${pkgdir}/usr/lib/python${_python_version}/site-packages
    mkdir -p "${_site_packages}"

    mv "${pkgdir}/usr/lib/python3/dist-packages"/* "${_site_packages}"
    rm -r "${pkgdir}/usr/lib/python3"
}