blob: 2a74c888c0cfe0bd27eab00e5fb54bcef67eef59 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Doug Newgard <scimmia at archlinux dot info>
# Contributor: Maciej Sieczka <msieczka at sieczka dot org>
pkgname=grass
pkgver=7.0.1
pkgrel=2
pkgdesc='Geospatial data management and analysis, image processing, graphics/maps production, spatial modeling and visualization'
arch=('i686' 'x86_64')
url='http://grass.osgeo.org/'
license=('GPL')
depends=('fftw' 'gdal' 'glu' 'xorg-server' 'wxpython' 'python2-matplotlib' 'python2-pillow')
source=("http://grass.osgeo.org/grass70/source/$pkgname-$pkgver.tar.gz")
sha256sums=('0987dd1618fde24b05785a502c7db8c09401a522a7a3ee50543068fab4eb405f')
prepare() {
cd $pkgname-$pkgver
ln -sf "$(which python2)" python
sed -i "s/env python$/&2/" $(find . -name "*.py")
sed -i 's/grass7$/grass70/' gui/icons/grass.desktop
}
build() {
cd $pkgname-$pkgver
export PATH="$srcdir/$pkgname-$pkgver:$PATH"
CPPFLAGS="" ./configure \
--prefix=/opt \
--with-wxwidgets=/usr/bin/wx-config \
--with-freetype-includes=/usr/include/freetype2
make
}
package() {
cd $pkgname-$pkgver
make exec_prefix="$pkgdir/usr" INST_DIR="$pkgdir/opt/$pkgname" install
sed -i "s|$pkgdir||g" "$pkgdir/opt/grass/demolocation/.grassrc70" "$pkgdir/usr/bin/grass70"
sed -i "s|$srcdir||g" "$pkgdir/opt/grass/docs/html/t.connect.html"
sed -i 's/"python"/"python2"/' "$pkgdir/usr/bin/grass70"
install -Dm644 gui/icons/grass-64x64.png "$pkgdir/usr/share/icons/grass.png"
install -Dm644 gui/icons/grass.desktop "$pkgdir/usr/share/applications/grass.desktop"
}
|