blob: f0e89f0c8d62e867a89ec74ef53b7d4340aa5ec3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: ventusliberum <dafeinayius@gmail.com>
pkgname=graviton
_pkgname=Graviton-App
pkgver=2.2.8
pkgrel=1
pkgdesc='A modern Code Editor'
arch=('x86_64')
url='https://graviton.netlify.app/'
license=('MIT')
depends=('libappindicator-gtk3' 'libnotify' 'libxss' 'nss' 'xdg-utils')
makedepends=('yarn' 'npm')
provides=("graviton")
conflicts=("graviton-bin")
source=("https://github.com/Graviton-Code-Editor/Graviton-App/archive/v${pkgver}.tar.gz"
'graviton.desktop'
'build.patch')
sha256sums=('794b2756f52d3c5f2175f1d5c088f5d3ff0b0f1b380f31df1dc278aeb286ca84'
'274abb2bef19694a483dc0f9d1bad14ad397b68e9e07f13580eac4cecc5163dd'
'021eac4c4cb19d3e425d716c15d4577b3ed9cdcb5b0a35fcb9115ac3efd823fc')
prepare() {
cd $srcdir/${_pkgname}-$pkgver
patch -Np1 -i "$srcdir/build.patch"
}
build() {
cd $srcdir/${_pkgname}-$pkgver
yarn
yarn build
}
package() {
# Install
cd "$srcdir/${_pkgname}-$pkgver/dist/linux-unpacked"
install -dm755 "$pkgdir/opt/Graviton Editor"
install -dm755 "$pkgdir/usr/bin"
cp -r * "$pkgdir/opt/Graviton Editor"
ln -s "/opt/Graviton Editor/graviton" "$pkgdir/usr/bin/graviton"
# Install Other things
install -Dm644 "$srcdir/${_pkgname}-$pkgver/LICENSE.md" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm644 "$srcdir/$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"
# Install icons
install -Dm644 "$srcdir/${_pkgname}-$pkgver/assets/logo.svg" "$pkgdir/usr/share/icons/$pkgname.svg"
}
|