PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

pkgname=groundcoverify-git
pkgver=0.2.1.r2.g9d6e2b4
pkgrel=4
pkgdesc="A simple python script which uses DeltaPlugin to turn regular groundcover in morrowind plugins into openmw-style groundcover."
arch=('i686' 'x86_64')
url="https://gitlab.com/bmwinger/groundcoverify"
license=('GPL')
depends=(delta-plugin python)
makedepends=(git)
provides=(groundcoverify)
source=('git+https://gitlab.com/bmwinger/groundcoverify' 'default_config_location.patch')
sha1sums=('SKIP' '269bfa832c49c014e507145285a496cc7e0bba9d')

pkgver() {
  cd "${srcdir}/groundcoverify"
  _tag="$(git describe --tags $(git rev-list --tags --max-count=1))"
  _numcommits="$(git rev-list $(git rev-list --tags --no-walk --max-count=1)..HEAD --count)"
  _hash="$(git rev-parse --short HEAD)"
  printf "%s.r%s.g%s" "$_tag" "$_numcommits" "$_hash"
}

prepare() {
  cd "${srcdir}/groundcoverify"
  patch -Np1 -i ../default_config_location.patch
}

package() {
  cd "${srcdir}/groundcoverify"
  install -Dm0755 -t "$pkgdir/usr/bin/" "groundcoverify.py"
  install -Dm0755 -t "$pkgdir/usr/share/groundcoverify/" "groundcoverify.toml"
}