PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Mantainer maz-1 < ohmygod19993 at gmail dot com >
pkgname=grub2-editor-frameworks
pkgver=0.6.4
pkgrel=1
pkgdesc="A KDE Control Module for configuring the GRUB2 bootloader.Unofficial KF5 port."
arch=('i686' 'x86_64')
url='https://ksmanis.wordpress.com/projects/grub2-editor/'
license=('GPL')
provides=grub2-editor
conflicts=grub2-editor
depends=('kdelibs4support' 'grub' 'kcmutils' 'kauth')
makedepends=('extra-cmake-modules' 'git' 'kdoctools')
source=("http://sourceforge.net/projects/kcm-grub2/files/kcm-grub2-$pkgver.tar.gz"
        "port_to_kf5.patch")
groups=('plasma')
md5sums=('b3ff8fb938be8112dcc6e42b3e56efc6'
         'SKIP')


prepare() {
  mkdir -p build
  cd kcm-grub2-$pkgver
  patch -p1 -i "$srcdir/port_to_kf5.patch"
}

build() {
  cd build
  cmake ../kcm-grub2-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIB_INSTALL_DIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DSYSCONF_INSTALL_DIR=/etc \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}