blob: 649408d48ad10a2a4472251ac8f0b2f03a0db5d7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: zlsun <zlsun1995 at gmail dot com>
# Contributor: Jonathan Steel <jsteel at archlinux.org>
# Contributor: DrZaius <lou at fakeoutdoorsman dot com>
# Contributor: Victor Feight <vrfeight3 at gmail dot com>
pkgname=gsimplecal-lunar
_pkgname=gsimplecal
pkgver=2.1
pkgrel=2
pkgdesc="Simple and lightweight GTK calendar with lunar calendar patch"
arch=('i686' 'x86_64')
url="http://dmedvinsky.github.com/$_pkgname"
license=('BSD')
depends=('gtk3' 'lunar-calendar')
conflicts=('gsimplecal')
provides=('gsimplecal')
_lunar_patch="$pkgname-$pkgver.patch"
source=("$_pkgname-$pkgver.tar.gz::https://github.com/dmedvinsky/$_pkgname/archive/v$pkgver.tar.gz"
$_lunar_patch)
md5sums=('170ac0bdc8663d97dec436e45b195491'
'SKIP')
prepare() {
cd "$_pkgname-$pkgver"
patch -p1 -i "$srcdir/$_lunar_patch"
}
build() {
cd "$_pkgname-$pkgver"
./autogen.sh
./configure --prefix=/usr
make
}
package() {
cd "$_pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$_pkgname/COPYING
}
|