summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: c06d5a0980a3d045025ec473b09d44acd0e2d777 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# Maintainer: Nasir A. <NasirA1991@users.noreply.github.com>
# Template consumed by .github/workflows/release.yml; 2.2.2 and a6a6bcc3d05b9024df4c05098baed69f29e52aa08b744f24f886c7f1c41fa00e
# are filled in only for the generated AUR package.
pkgname=gsp370-tray
pkgver=2.2.2
pkgrel=1
pkgdesc='Tray and Plasma widget for the Sennheiser/EPOS GSP 370 (battery and sidetone)'
arch=('x86_64' 'aarch64')
url='https://github.com/NasirA1991/gsp370-tray'
license=('MIT')
depends=('dbus' 'gcc-libs' 'glibc')
makedepends=('rust')
optdepends=('libnotify: low-battery notifications'
            'plasma-workspace: KDE Plasma panel widget')
options=('!debug')
install=gsp370-tray.install
source=("$pkgname-$pkgver-source.tar.gz::$url/releases/download/v$pkgver/$pkgname-$pkgver-source.tar.gz")
sha256sums=('a6a6bcc3d05b9024df4c05098baed69f29e52aa08b744f24f886c7f1c41fa00e')

build() {
    cd "$srcdir/$pkgname-$pkgver"
    export CARGO_HOME="$srcdir/cargo-home"
    export RUSTFLAGS="${RUSTFLAGS:-} --remap-path-prefix=$srcdir=/build"
    cargo build --release --locked --manifest-path rust/Cargo.toml
}

check() {
    cd "$srcdir/$pkgname-$pkgver"
    export CARGO_HOME="$srcdir/cargo-home"
    export RUSTFLAGS="${RUSTFLAGS:-} --remap-path-prefix=$srcdir=/build"
    cargo test --release --locked --manifest-path rust/Cargo.toml
}

package() {
    cd "$srcdir/$pkgname-$pkgver"
    install -Dm755 rust/target/release/gsp370-tray "$pkgdir/usr/bin/gsp370-tray"
    install -Dm644 packaging/gsp370-tray.desktop \
        "$pkgdir/usr/share/applications/gsp370-tray.desktop"
    install -Dm644 packaging/gsp370-tray.svg \
        "$pkgdir/usr/share/icons/hicolor/scalable/apps/gsp370-tray.svg"
    install -Dm644 packaging/70-gsp370.rules \
        "$pkgdir/usr/lib/udev/rules.d/70-gsp370.rules"
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    install -Dm644 rust/assets/NotoSans-OFL.txt \
        "$pkgdir/usr/share/licenses/$pkgname/NotoSans-OFL.txt"
    install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
    install -Dm644 docs/protocol.md "$pkgdir/usr/share/doc/$pkgname/docs/protocol.md"
    install -Dm644 docs/tray-icon.png "$pkgdir/usr/share/doc/$pkgname/docs/tray-icon.png"
    install -d "$pkgdir/usr/share/plasma/plasmoids/org.nasir.gsp370battery"
    cp -a packaging/plasmoid/gsp370battery/. \
        "$pkgdir/usr/share/plasma/plasmoids/org.nasir.gsp370battery/"
}