PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: David Čudek <inzenyrak at seznam dot cz> 
# Contributor: David Čudek <inzenyrak at seznam dot cz>
pkgname=gst-plugin-viper4linux-git
_gitname=gst-plugin-viperfx
pkgver=r36.a5c1b03
pkgrel=2
pkgdesc="ViPER FX core wrapper plugin for gstreamer"
arch=('x86_64')
url="https://github.com/Audio4Linux/gst-plugin-viperfx"
license=('custom')
depends=('gst-plugins-base-libs' 'libviperfx')
makedepends=('git' 'cmake')
provides=("${pkgname%-git}" 'gst-plugin-viperfx' 'libgstviperfx.so')
conflicts=("${pkgname%-git}" 'gst-plugin-viperfx' 'gst-plugin-jamesdsp')
source=('git+https://github.com/Audio4Linux/gst-plugin-viperfx.git')
sha256sums=('SKIP')

pkgver() {
  cd gst-plugin-viperfx
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cmake -B build -S gst-plugin-viperfx \
    -DCMAKE_BUILD_TYPE='None' \
    -DCMAKE_INSTALL_PREFIX='/usr' \
    -DCMAKE_C_FLAGS="-Wno-incompatible-pointer-types -fpermissive" \
    -DCMAKE_CXX_FLAGS="-Wno-incompatible-pointer-types -fpermissive" \
    -Wno-dev
  make -C build
}

package() {
  install -Dm755 build/libgstviperfx.so -t "$pkgdir/usr/lib/gstreamer-1.0/"

  cd gst-plugin-viperfx
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/${pkgname%-git}/"
}