blob: 73212e661ecebbf49fcd859c21aa6c869715334b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Original Package: Jan de Groot <jgc@archlinux.org>
# Maintainer: Lubosz Sarnecki <lubosz@gmail.com>
# Maintainer: Solomon Choina <shlomochoina@gmail.com>
pkgname=gst-plugins-bad-git
pkgver=1.18.0.r589.g99ebbf72e
pkgrel=1
pkgdesc="GStreamer Multimedia Framework Bad Plugins"
arch=('i686' 'x86_64')
license=('LGPL')
provides=('gst-plugins-bad='$pkgver)
conflicts=('gst-plugins-bad' 'gst-plugins-gl')
url="http://gstreamer.freedesktop.org/"
depends=('mjpegtools' 'gst-plugins-base-git' 'curl'
'chromaprint' 'libmms' 'faad2' 'mpg123'
'faac' 'celt' 'libdca' 'soundtouch' 'spandsp'
'libdvdnav' 'libmodplug' 'libgme' 'opus'
'wayland' 'rtmpdump' 'opencv' 'vulkan-headers'
'bluez-libs' 'intel-media-sdk' 'libbs2b' 'libfdk-aac'
'fluidsynth' 'dssim' 'libkate' 'liblrdf'
'ladspa' 'libde265' 'libmicrodns' 'libmpcdec'
'neon' 'libofa' 'openal' 'openh264'
'libopenmpt' 'openni2' 'sbc' 'srt' 'libsrtp'
'zvbi' 'vo-aacenc' 'vo-amrwbenc' 'shaderc'
'libnice' 'webrtc-audio-processing' 'wildmidi'
'zbar' 'lilv-git' 'vulkan-icd-loader'
'libldac' 'libopenaptx'
)
makedepends=('git' 'meson' 'schroedinger'
'libexif' 'libdvdread' 'lilv-git'
'libvdpau' 'libmpeg2'
'gtk-doc' 'glu' 'gobject-introspection' )
options=(!emptydirs)
source=('git+https://anongit.freedesktop.org/git/gstreamer/gst-plugins-bad.git'
'gst-common::git+https://gitlab.freedesktop.org/gstreamer/common.git')
sha256sums=('SKIP'
'SKIP')
_gitname='gst-plugins-bad'
pkgver() {
cd $_gitname
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd $_gitname
git submodule init
git config --local submodule.common.url "$srcdir/gst-common"
git submodule update
# openexr 2.4 requires c++11
sed -e "s|'-std=c++98'||" -i ext/openexr/meson.build
}
build() {
arch-meson $_gitname build \
-Dopensles=disabled \
-Dtinyalsa=disabled \
-Dwasapi=disabled \
-Davtp=disabled \
-Ddirectfb=disabled \
-Dflite=disabled \
-Dsctp=disabled \
-Dwpe=disabled \
-Ddoc=disabled \
-Dmagicleap=disabled \
-Dwasapi2=disabled \
-Disac=disabled \
-Dzxing=disabled \
-Dpackage-name="GStreamer Bad Plugins (Arch Linux)" \
-Dpackage-origin="https://www.archlinux.org/"
ninja -C build
}
package() {
DESTDIR="${pkgdir}" ninja -C build install
}
|