blob: 48224a7eb504369d43d661a7d5c7e160937be0e1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Fabio 'Lolix' Loli <lolix@disroot.org>
# Contributor: Nikola Hadžić <nikola@firemail.cc>
pkgname=gst-plugins-rs
pkgver=0.9.7
pkgrel=1
pkgdesc="GStreamer plugins written in Rust"
arch=(x86_64)
url="https://gitlab.freedesktop.org/gstreamer/gst-plugins-rs"
license=(Apache LGPL2.1 MIT MPL2)
depends=(gstreamer gtk4 dav1d libsodium libwebp)
makedepends=(git rust meson cargo-c clang hotdoc)
options=(!lto)
source=("git+https://gitlab.freedesktop.org/gstreamer/gst-plugins-rs.git#tag=${pkgver}")
sha256sums=(SKIP)
prepare() {
cd "${srcdir}/${pkgname}"
cargo fetch --target x86_64-unknown-linux-gnu --manifest-path "${srcdir}/${pkgname}/Cargo.toml"
}
build() {
cd "${srcdir}/${pkgname}"
arch-meson build \
-D csound=disabled \
-D dav1d=enabled \
-D sodium=enabled
ninja -C build
}
package() {
cd "${srcdir}/${pkgname}"
DESTDIR="${pkgdir}" meson install -C build
install -D LICENSE-* -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|