blob: 4c77a76e45e8591e786533486815264fb7083af7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Maintainer : Daniel Bermond < gmail-com: danielbermond >
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=gst-plugins-ugly-git
_srcname=gst-plugins-ugly
pkgver=1.15.0.1.r5505.g59d43105
pkgrel=1
pkgdesc='GStreamer Multimedia Framework Ugly Plugins (git version)'
arch=('i686' 'x86_64')
url='https://gstreamer.freedesktop.org/'
license=('LGPL')
depends=(
# official repositories:
'libdvdread' 'libmpeg2' 'a52dec' 'libsidplay' 'libcdio'
'x264' 'opencore-amr'
# AUR:
'gstreamer-git' 'gst-plugins-base-git'
)
makedepends=('git' 'python' 'gtk-doc' 'autoconf-archive')
provides=("gst-plugins-ugly=${pkgver%%.r*}")
conflicts=('gst-plugins-ugly')
source=('git+https://anongit.freedesktop.org/git/gstreamer/gst-plugins-ugly.git'
'gst-common'::'git+https://anongit.freedesktop.org/git/gstreamer/common.git')
sha256sums=('SKIP'
'SKIP')
prepare() {
cd "$_srcname"
git submodule init
git config --local submodule.common.url "${srcdir}/gst-common"
git submodule update
NOCONFIGURE='1' ./autogen.sh
}
pkgver() {
cd "$_srcname"
local _version
local _revision
local _shorthash
_version="$(grep 'AC_INIT' configure.ac | sed 's/,\[http.*//;s/AC_INIT.*\],//;s/.*\[\([^]]*\)\].*/\1/g')"
_revision="$(git rev-list --count HEAD)"
_shorthash="$(git rev-parse --short HEAD)"
printf '%s.r%s.g%s' "$_version" "$_revision" "$_shorthash"
}
build() {
cd "$_srcname"
./configure \
--prefix='/usr' \
--sysconfdir='/etc' \
--localstatedir='/var' \
--libexecdir='/usr/lib' \
--enable-shared \
--disable-static \
--enable-experimental \
--enable-gtk-doc \
--with-package-name='GStreamer Ugly Plugins (Arch Linux)' \
--with-package-origin='http://www.archlinux.org/'
# https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() {
cd "$_srcname"
make check
}
package() {
cd "$_srcname"
make DESTDIR="$pkgdir" install
}
|