summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 6b15038115e406509190efecbb785953126ccf39 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Contributor: Lex Black <autumn-wind at web dot de>
# Contributor: György Balló <ballogy@freestart.hu>

_pkgname=gtk-sharp
pkgname=$_pkgname-git
pkgver=2.99.3.r39.g89b2dae
pkgrel=1
pkgdesc="C# bindings to the cross platform Gtk+ GUI toolkit (git-master)"
arch=('i686' 'x86_64')
url="http://www.mono-project.com/docs/gui/gtksharp/"
license=('LGPL')
depends=('mono' 'gtk3')
makedepends=('git')
conflicts=('gtk-sharp-3')
provides=('gtk-sharp-3=2.99.3')
source=('git://github.com/mono/gtk-sharp.git#branch=master')
md5sums=('SKIP')


pkgver() {
	cd $_pkgname
	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
	cd "$srcdir/$_pkgname"

	./autogen.sh --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
		--disable-static
	make
}

package() {
	cd "$srcdir/$_pkgname"

	make DESTDIR="$pkgdir/" install
	rm -r "$pkgdir"/usr/lib/monodoc
}