blob: 37fccf0fcc55abc5ee76d6e68d2395da12c3459b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# $Id$
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
_rls=1
_pkgname=gtk3
pkgname=$_pkgname-donnatella
pkgver=3.18.4
pkgrel=1
pkgdesc="GObject-based multi-platform GUI toolkit (v3) w/ fixes & extra features"
arch=(i686 x86_64)
url="http://www.gtk.org/"
install=gtk3.install
depends=(atk cairo gtk-update-icon-cache libcups libxcursor libxinerama
libxrandr libxi libepoxy libxcomposite libxdamage pango
shared-mime-info colord at-spi2-atk wayland libxkbcommon
adwaita-icon-theme json-glib rest)
makedepends=(gobject-introspection libcanberra)
optdepends=('libcanberra: gtk3-widget-factory demo')
provides=($_pkgname)
conflicts=($_pkgname)
license=(LGPL)
source=(http://ftp.gnome.org/pub/gnome/sources/gtk+/${pkgver%.*}/gtk+-$pkgver.tar.xz
settings.ini
http://jjacky.com/donnatella/$pkgname-${pkgver}-$_rls.tar.gz)
sha256sums=('5400dcf280d28d24606f33d59ed48c717f7d3db425d4b6fb52e8002f0c76c7eb'
'14369dfd1d325c393e17c105d5d5cc5501663277bd4047ea04a50abb3cfbd119'
'a0bac9f79b8fa8b686421300a492b2875b79acfabb7943a3a6ab60cdd7cec56b')
prepare() {
cd "gtk+-$pkgver"
for patch in ../*.patch; do
patch -p1 -i $patch
done
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd "gtk+-$pkgver"
CXX=/bin/false ./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--disable-schemas-compile \
--enable-x11-backend \
--enable-broadway-backend \
--enable-wayland-backend
#https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd "gtk+-$pkgver"
make DESTDIR="$pkgdir" install
rm -f "$pkgdir/usr/bin/gtk-update-icon-cache"
}
|