PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: ssf <punx69 at gmx dot net>
 
pkgname=gtk3-nocsd-git
pkgver=2.r36
pkgrel=1
pkgdesc="A hack to disable gtk+ 3 client side decoration"
arch=('x86_64')
url='https://github.com/PCMan/gtk3-nocsd'
license=('GPL2')
depends=('gtk3')
makedepends=('pkg-config' 'gtk3')
provides=("${pkgname//-git/}=${pkgver}")
source=("${pkgname//-git/}::git://github.com/PCMan/gtk3-nocsd.git")
sha1sums=('SKIP')
 
pkgver() {
	cd ${pkgname//-git/}
	_ver=$(git describe --abbrev=0 --tags|sed 's/^v//')
	_rev=$(git rev-list --count HEAD)
	printf "$_ver.r$_rev"
}

build() {
	cd ${pkgname//-git/}
	make
}

package() {
	install -Dm644 $srcdir/${pkgname//-git/}/libgtk3-nocsd.so.0 $pkgdir/usr/lib/libgtk3-nocsd.so.0
	install -d $pkgdir/etc/profile.d
	cat <<\EOF >>$pkgdir/etc/profile.d/gtk3-nocsd.sh
##disables overlay scrolling in newer GTK3 versions
export GTK_OVERLAY_SCROLLING=0
##No silly CSD stuff
export GTK_CSD=0
export LD_PRELOAD=/usr/lib/libgtk3-nocsd.so.0
EOF
	chmod +x $pkgdir/etc/profile.d/gtk3-nocsd.sh
}