blob: 585d268809dea5719723d1167117611b082e5231 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
# Contributor: Luis Martinez <luis dot martinez at disroot dot org>
pkgname=gtree
pkgver=1.10.10
pkgrel=1
pkgdesc="Generates tree from Markdown or programmatically"
arch=(x86_64 i686 aarch64)
url="https://github.com/ddddddO/${pkgname}"
license=(BSD-2-clause)
depends=(glibc)
makedepends=(go)
source=(${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz)
sha512sums=('d02acab1b2db6136baf5fd4a824ddd3a793a205cb9dc5529f021f60dd2618edb065e112634deae9ecad9afaa496af9a07c751ee587ad6ed51cbedc4f8215a3af')
prepare() {
cd ${pkgname}-${pkgver}
mkdir -p build
go mod download
}
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
cd ${pkgname}-${pkgver}
go build \
-o build \
-ldflags "-linkmode external -extldflags \"${LDFLAGS}\"" \
./cmd/gtree
}
check() {
cd ${pkgname}-${pkgver}
go test .
}
package() {
cd ${pkgname}-${pkgver}
install -Dv build/gtree -t "$pkgdir/usr/bin/"
install -Dvm644 LICENSE -t "$pkgdir/usr/share/licenses/${pkgname}"
}
|