PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Maintainer: Michael DeGuzis <mdeguzis@gmail.com>

pkgname=guacamole-server-git
_gitname=guacamole-server
pkgver=0.9.12.incubating.r68.g04205a9b
pkgrel=1
pkgdesc="Guacamole proxy daemon"
arch=('i686' 'x86_64')
url="http://guacamole.sourceforge.net/"
license=('GPL3')
replaces=('guacd' 'libguac' 'libguac-client-ssh' 'libguac-client-vnc' 'libguac-client-rdp')
depends=('pango' 'openssl' 'libvorbis' 'uuid' 'libwebp')
makedepends=('git' 'libpulse' 'libvorbis' 'openssl-1.0' 'libssh' 'libvncserver' 'pango' 'libtelnet')
optdepends=('libssh: for ssh protocol support'
'libvncserver: for vnc protocol support'
'freerdp: for rdp protocol support'
'libpulse: for pulseaudio support'
'libtelnet: for telnet protocol support'
)

source=(
		"$_gitname::git+https://github.com/apache/incubator-guacamole-server.git" 
		'guacd.service'
	   )
 
md5sums=('SKIP'
         'dfaa29349d2e73af6dac75d6cafbd762')
 
pkgver() {
  cd "$srcdir"/$_gitname
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
	cd "$srcdir"/$_gitname
	autoreconf -fi
	PKG_CONFIG_PATH=/usr/lib/openssl-1.0/pkgconfig \
	CFLAGS+=" -I/usr/include/openssl-1.0" \
	LDFLAGS+=" -L/usr/lib/openssl-1.0 -lssl" \
	./configure \
		--with-openssl \
		--prefix=/usr \
		--sbindir=/usr/bin \
		CPPFLAGS="-Wno-error=pedantic"
	make
}
 
package() {
	cd "$srcdir"/$_gitname
	make DESTDIR="$pkgdir" install
	mkdir -p "$pkgdir"/usr/lib/systemd/system/
	install -Dm644 "$srcdir"/guacd.service "$pkgdir"/usr/lib/systemd/system/
}