blob: c1cdbb517d7e4206a69eee8f90e5bc6682ac6c9f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
pkgname=guile-emacs-git
pkgver=116892.41120e0f59
pkgrel=1
pkgdesc="branch of GNU Emacs that replaces Emacs' own EmacsLisp engine with that of Guile."
arch=('i686' 'x86_64')
url="http://www.emacswiki.org/emacs/GuileEmacs"
license=('GPL3')
depends=('guile4emacs-git' 'gtk3' 'alsa-lib' 'imagemagick' 'gpm'
'm17n-lib' 'desktop-file-utils' 'gc' 'gnutls')
makedepends=('git' 'clang' 'gconf')
conflicts=('emacs' 'ctags')
provides=('emacs' 'ctags')
options=('!strip' '!makeflags')
source=("guilemacs::git://git.hcoop.net/git/bpt/emacs.git#branch=wip" )
sha256sums=('SKIP')
_gitname="guilemacs"
pkgver() {
cd "$srcdir"/"$_gitname"
printf "%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "$srcdir/$_gitname"
[[ -x configure ]] || ./autogen.sh
}
build() {
cd "$srcdir"/"$_gitname"
# Avoid hardening-wrapper (taken from emacs-pretest, thanks to Thomas Jost).
export PATH=$(echo "$PATH" | sed 's!/usr/lib/hardening-wrapper/bin!!g')
CC=clang ./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--libexecdir=/usr/lib \
--with-jpeg=no \
--mandir=/usr/share/man \
--with-gameuser=:games \
--with-sound=alsa \
--with-xft \
--with-modules \
--with-x-toolkit=gtk3 \
--without-gconf \
--with-gsettings
make
}
package() {
cd $srcdir/guilemacs
make DESTDIR="$pkgdir/" install
chown -R root:root $pkgdir/usr
# remove conflict with the texinfo-package
rm $pkgdir/usr/share/info/info.info.gz
}
|