blob: 75424561a772710d91de33563e3429f61391b754 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
pkgname=guiscrcpy-git
pkgver=4.11.0.r1270.gd7a36da
pkgrel=2
pkgdesc="Open Source GUI based Android Screen Mirroring System"
arch=('any')
url="https://guiscrcpy.github.io"
license=('GPL3')
depends=('scrcpy' 'python-pynput' 'python-qtpy' 'python-psutil'
'python-cairosvg' 'python-click' 'python-colorama' 'libxinerama')
makedepends=('git' 'python-dephell')
optdepends=('usbaudio: audio mirroring for Android <8.0'
'sndcpy: audio mirroring for Android >=10')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/srevinsaju/guiscrcpy.git')
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/${pkgname%-git}"
printf "%s.r%s.g%s" "$(sed -n '/version/{s/.*"\([0-9\.]*\).*"/\1/p;q}' pyproject.toml)" \
"$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "$srcdir/${pkgname%-git}"
dephell deps convert --from pyproject.toml --to setup.py
}
build() {
cd "$srcdir/${pkgname%-git}"
python setup.py build
}
package() {
cd "$srcdir/${pkgname%-git}"
python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
install -Dm644 appimage/${pkgname%-git}.desktop -t "$pkgdir/usr/share/applications"
install -Dm644 appimage/${pkgname%-git}.png -t "$pkgdir/usr/share/pixmaps"
}
|