blob: 1eb1b2b433f4418bfa704e784788740680ad9943 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Gimmeapill <gimmeapill at gmail dot com>
# Contributor: sekret
# Contributor: Army
# Contributor: Funkmuscle
# Contributor: David Runge <dvzrv@archlinux.org
pkgname=guitarix-git
pkgver=0.46.0.r4.g3964866a
pkgrel=1
pkgdesc="virtual guitar amplifier for Jack/Linux"
arch=('x86_64')
url="https://guitarix.org"
license=('GPL3')
groups=('ladspa-plugins' 'lv2-plugins' 'pro-audio')
depends=('jack' 'gtkmm3' 'liblo' 'liblrdf' 'libsndfile' 'lilv' 'bluez-libs' 'boost-libs'
'zita-convolver' 'zita-resampler' 'ttf-roboto')
makedepends=('git' 'boost' 'eigen' 'gperf' 'intltool' 'ladspa' 'lv2' 'waf' 'sassc' 'pkgconfig')
provides=('lv2-host' 'libgxw.so' 'libgxwmm.so')
conflicts=('guitarix')
replaces=('guitarix2')
source=("${pkgname%-*}::git+https://github.com/brummer10/guitarix")
md5sums=('SKIP')
pkgver() {
cd "${pkgname%-*}"
git describe --long --tags | sed -r 's/^V//;s/([^-]*-g)/r\1/;s/-/./g'
}
build() {
cd "${pkgname%-*}/trunk"
./waf configure --prefix=/usr \
--optimization \
--includeresampler \
--includeconvolver \
--enable-nls \
--no-faust \
--shared-lib \
--lib-dev \
--cxxflags='-flto' \
--ldflags="${LDFLAGS}"
./waf build -vv
}
package() {
cd "${pkgname%-*}/trunk"
./waf install --destdir="${pkgdir}"
# docs
install -vDm 644 {changelog,README} -t "${pkgdir}/usr/share/doc/${pkgname}/"
}
|