PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Bernhard Landauer <oberon@manjaro.org>
# Maintainer: Tobias Frilling <tobias@frilling-online.de>

pkgname=guvcview-qt5-git
pkgver=2.0.4.r33.gf618a10
pkgrel=1
pkgdesc="Video viewer and capturer for the linux uvc driver, Qt5-version"
arch=('i686' 'x86_64')
url="http://guvcview.sourceforge.net/"
license=('GPL')
depends=('ffmpeg'
	'gsl'
	'libpng'
	'libusb'
	'portaudio'
	'qt5-base'
	'sfml'
	'sdl2')
makedepends=('git'
	'intltool'
	'qt5-tools')
optdepends=('pulseaudio: for PulseAudio support')
provides=('guvcview')
conflicts=('guvcview')
source=("$pkgname::git://git.code.sf.net/p/guvcview/git-master")
md5sums=('SKIP')

pkgver() {
  cd $srcdir/$pkgname
  git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "$srcdir/$pkgname"

  export CPPFLAGS+=" -O2 "
  export CXXFLAGS="-std=c++11"
  ./bootstrap.sh --prefix=/usr
  ./configure --prefix=/usr \
    --disable-gtk3 \
    --enable-qt5 \
    --disable-debian-menu \
    --enable-sfml
  make
}

package() {
  cd "$srcdir/$pkgname"
  make DESTDIR="$pkgdir/" install
}