summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 738266da88fb46a5c6f3db1e2417f2ae687b5ed0 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# Maintainer: Antonio Rojas <arojas@archlinux.org>

pkgname=gwenview-git
pkgver=r5432.be0da0e
pkgrel=1
pkgdesc='A fast and easy to use image viewer for KDE'
arch=('i686' 'x86_64')
url='http://kde.org/applications/graphics/gwenview/'
license=('GPL')
depends=('kactivities-frameworks' 'kdelibs4support' 'exiv2' 'libkdcraw-git' 'libkipi-git')
makedepends=('extra-cmake-modules' 'git' 'kdoctools' 'python')
conflicts=('kdegraphics-gwenview' 'gwenview')
provides=('gwenview')
source=("git://anongit.kde.org/gwenview.git")
install=$pkgname.install
sha256sums=('SKIP')

pkgver() {
  cd gwenview
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p build
}

build() { 
  cd build
  cmake ../gwenview \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DLIB_INSTALL_DIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}