blob: 0cc99afc82aec72bdefe71573553ca117ff8bf0b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: oysstu <oysstu at gmail dot com>
pkgname=gz-rendering7
pkgver=7.4.2
pkgrel=5
_pkgmaj=${pkgver%%.*}
_pkgbase=${pkgname::-${#_pkgmaj}}
pkgdesc="C++ library designed to provide an abstraction for different rendering engines."
arch=('any')
url="https://github.com/gazebosim/${_pkgbase}"
license=('Apache')
depends=(
'freeimage'
'gz-common=5'
'gz-math=7'
'gz-plugin=2'
'gz-utils=2'
'ogre-next<3.0.0'
)
makedepends=(
'cmake'
'boost'
'doxygen'
'gz-cmake=3'
)
optdepends=(
'optix: Nvidia OptiX rendering engine plugin'
'ogre-1.9: Ogre 1.x rendering enging plugin'
)
provides=("${_pkgbase}=${_pkgmaj}")
source=("https://github.com/gazebosim/${_pkgbase}/archive/${pkgname}_${pkgver}.tar.gz")
sha256sums=('b35d41ae611f96bb755aa4dd1f31b389f514220bdae9192d24ba2b17cbcd2def')
_build_dir="${_pkgbase}-${pkgname}_${pkgver}/build"
build() {
mkdir -p "$srcdir/$_build_dir" && cd $_
cmake .. -DCMAKE_BUILD_TYPE='None' \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DBUILD_TESTING=OFF \
-Wno-dev
cmake --build .
}
package() {
DESTDIR="$pkgdir" cmake --install "$srcdir/$_build_dir"
}
|