blob: 49217a5d1dbfe96d61eb4f007459e3e27e4b695a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: oysstu <oysstu at gmail dot com>
pkgname=gz-rendering8
pkgver=8.2.3
pkgrel=1
_pkgmaj=${pkgver%%.*}
_pkgbase=${pkgname::-${#_pkgmaj}}
pkgdesc="C++ library designed to provide an abstraction for different rendering engines."
arch=('any')
url="https://github.com/gazebosim/${_pkgbase}"
license=('Apache-2.0')
depends=(
'freeimage'
'gz-common=5'
'gz-math=7'
'gz-plugin=2'
'gz-utils=2'
'ogre-next2'
)
makedepends=(
'cmake'
'boost'
'doxygen'
'gz-cmake=3'
'vulkan-headers'
)
optdepends=(
'optix: Nvidia OptiX rendering engine plugin'
'ogre-1.9: Ogre 1.x rendering enging plugin'
)
provides=("${_pkgbase}=${_pkgmaj}")
source=("https://github.com/gazebosim/${_pkgbase}/archive/${pkgname}_${pkgver}.tar.gz"
"https://github.com/gazebosim/${_pkgbase}/pull/1128.patch")
sha256sums=('5bfe18d164414e098b2ba6ef81bf9391f7ff8f2c39b8a4fa9f8543f778e921c8'
'2c9939d6d5eeb4b669267d09266e45a7dc0d387bf3e1b01510acc5090a6be92d')
_build_dir="${_pkgbase}-${pkgname}_${pkgver}/build"
prepare() {
cd "${_pkgbase}-${pkgname}_${pkgver}"
patch -p1 < ${srcdir}/1128.patch
}
build() {
mkdir -p "$srcdir/$_build_dir" && cd $_
cmake .. -DCMAKE_BUILD_TYPE='None' \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DCMAKE_INSTALL_LIBEXECDIR="lib/$pkgname" \
-DBUILD_TESTING=OFF \
-DUSE_UNOFFICIAL_OGRE_VERSIONS=ON \
-Wno-dev
cmake --build .
}
package() {
DESTDIR="$pkgdir" cmake --install "$srcdir/$_build_dir"
}
|