blob: 36fe1e8f9b70363ca1132a3e2a94c9d2edf54043 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: oysstu <oysstu at gmail dot com>
pkgname=gz-sensors8
pkgver=8.0.0
pkgrel=2
_pkgmaj=${pkgver%%.*}
_pkgbase=${pkgname::-${#_pkgmaj}}
pkgdesc="Provides numerous sensor models designed to generate realistic data from simulation environments."
arch=('any')
url="https://github.com/gazebosim/${_pkgbase}"
license=('Apache')
depends=(
'gz-common=5'
'gz-math=7'
'gz-msgs=10'
'gz-rendering=8'
'gz-transport=13'
'protobuf'
'sdformat=14'
)
makedepends=(
'cmake'
'doxygen'
'gz-cmake=3'
)
provides=("${_pkgbase}=${_pkgmaj}")
source=("https://github.com/gazebosim/${_pkgbase}/archive/${pkgname}_${pkgver}.tar.gz")
sha256sums=('f86d6572f31efc199a623462faaa1b380c91a3706a60561aa498562aa939184e')
build() {
cmake -B build -S "${_pkgbase}-${pkgname}_${pkgver}" \
-DCMAKE_BUILD_TYPE='None' \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DBUILD_TESTING=OFF \
-Wno-dev
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
}
|