blob: 17cef4a96509e5d84522deadd21e36f2c691e167 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
pkgname="hack-browser-data"
pkgver=1.0.0
pkgrel=1
pkgdesc="Extract and decrypt browser data, supporting multiple data types"
arch=(
'aarch64'
'armv7h'
'i686'
'x86_64'
)
url="https://github.com/moonD4rk/HackBrowserData"
license=(
'MIT'
)
depends=(
'glibc'
)
makedepends=(
'git'
'go'
)
_pkgsrc="${url##*/}"
source=(
"${_pkgsrc}::git+${url}.git#tag=v${pkgver}"
)
b2sums=('d21ceab975d5c7f1746779b6d83da92eeb7e49d59b2a5a99f5758cc829dd79b6d87bb3930d361f3917458b16503f9904c6e8a4d7c17366bdaf10ba6aa8e11b30')
prepare() {
export GOMODCACHE="${srcdir}/go-mod-cache"
cd "${srcdir}/${_pkgsrc}"
go mod download -modcacherw -x
go mod verify
}
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOCACHE="${srcdir}/go-cache"
export GOMODCACHE="${srcdir}/go-mod-cache"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
cd "${srcdir}/${_pkgsrc}"
go build -v -o "build/${pkgname}" -ldflags "\
-X main.version=${pkgver} \
-X main.commit=$(git rev-parse --short HEAD) \
-X main.buildDate=$(date --utc --date="@${SOURCE_DATE_EPOCH:-$(date +%s)}" +"%Y-%m-%dT%H:%M:%SZ")" \
./"cmd/${pkgname}"
}
check() {
cd "${srcdir}/${_pkgsrc}"
go test ./...
}
package() {
cd "${srcdir}/${_pkgsrc}"
install -vDm755 "build/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
# install -vDm644 "README_ZH.md" "${pkgdir}/usr/share/doc/${_pkgname}/README_ZH.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|