blob: 757bd21c920e5054b2e20361a4dca375d5e87353 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: noraj <printf %s 'YWxleGFuZHJlLnphbm5pQGV1cm9wZS5jb20='|base64 -d>
pkgname=haiti
_gemname=haiti-hash
pkgver=2.0.0
pkgrel=2
pkgdesc='Hash type identifier (CLI & lib)'
arch=('any')
url='https://noraj.github.io/haiti/'
license=('MIT')
depends=('ruby' 'ruby-paint' 'ruby-docopt')
options=(!emptydirs)
source=("https://rubygems.org/downloads/$_gemname-$pkgver.gem")
#source=("https://github.com/noraj/$pkgname/archive/v$pkgver.tar.gz")
noextract=("$_gemname-$pkgver.gem")
b2sums=('6390629ff0209e3950f7890c0f109e5aecf2e9ae8babcbbed7396c608e822d6a430ca65809cc80b2aa085b6465f48e96a338b940afea5bf823dea6c71fca9013')
package() {
_gemdir="$(ruby -e'puts Gem.default_dir')"
gem install --ignore-dependencies --no-user-install --no-document \
-i "$pkgdir/$_gemdir" -n "$pkgdir/usr/bin" $_gemname-$pkgver.gem
rm "$pkgdir/$_gemdir/cache/$_gemname-$pkgver.gem"
find "$pkgdir/$_gemdir/extensions/" -name *.so -delete
install -D -m644 "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/LICENSE.txt" \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -D -m644 "$pkgdir/$_gemdir/gems/$_gemname-$pkgver/man/$pkgname.1" \
"$pkgdir/usr/share/man/man1/$pkgname.1"
}
|