blob: d0f47f8786cc9e8c3678dfe04da1e5cb1e9c07ab (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
pkgname=halley
pkgver=0.5.0
pkgrel=1
pkgdesc="Spatial Wayland compositor built around infinite workspace navigation"
arch=('x86_64')
url="https://github.com/saltnpepper97/halley"
license=('GPL-3.0-only')
depends=(
'wayland'
'libxkbcommon'
'libinput'
'seatd'
'mesa'
'libdisplay-info'
'libdrm'
)
makedepends=(
'rust'
'cargo'
'pkgconf'
)
optdepends=(
'halley-lift: native search and action launcher'
'xdg-desktop-portal-halley: native ScreenCast/Screenshot portal backend'
'xwayland-satellite: X11 application support'
'fuzzel: launcher bound to Super+d by default'
'ghostty: terminal for the default open-terminal binding'
'kitty: terminal for the default open-terminal binding'
'foot: terminal for the default open-terminal binding'
'wezterm: terminal for the default open-terminal binding'
'alacritty: terminal for the default open-terminal binding'
'wireplumber: provides wpctl for default media-key bindings'
'gamescope: game launch wrapping through halleyctl gamescope'
)
options=('!debug' '!lto')
source=("$pkgname-$pkgver.tar.gz::https://github.com/saltnpepper97/halley/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('b8f1755a76586cdde93e464db70039d8beaffb52241f6976b12b66329dde7eee')
build() {
cd "$srcdir/$pkgname-$pkgver"
export CARGO_TARGET_DIR=target
cargo build --release --locked -p halley -p halley-cli
}
check() {
cd "$srcdir/$pkgname-$pkgver"
cargo test --release --locked -p halley-cli --no-fail-fast || true
}
package() {
cd "$srcdir/$pkgname-$pkgver"
install -Dm755 "target/release/halley" \
"$pkgdir/usr/bin/halley"
install -Dm755 "target/release/halleyctl" \
"$pkgdir/usr/bin/halleyctl"
install -Dm755 "packaging/wayland-sessions/halley-session" \
"$pkgdir/usr/bin/halley-session"
install -Dm644 "packaging/wayland-sessions/halley.desktop" \
"$pkgdir/usr/share/wayland-sessions/halley.desktop"
install -Dm644 "packaging/systemd-user/halley.service" \
"$pkgdir/usr/lib/systemd/user/halley.service"
install -Dm644 "packaging/systemd-user/halley-shutdown.target" \
"$pkgdir/usr/lib/systemd/user/halley-shutdown.target"
install -Dm644 "LICENSE" \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|