blob: e96256465a6e902fcf72d764fd91f34bb62a5ec0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: James Bunton <jamesbunton@delx.net.au>
# Contributor: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Sebastien Piccand <sebcactus gmail com>
pkgname=('handbrake-fdkaac' 'handbrake-cli-fdkaac')
pkgver=1.3.2
pkgrel=1
arch=('x86_64')
url="https://handbrake.fr/"
license=('GPL')
_commondeps=('libxml2' 'libass' 'libvorbis' 'opus' 'speex' 'libtheora' 'lame'
'x264' 'jansson' 'libvpx' 'libva' 'numactl'
'bzip2' 'gcc-libs' 'zlib' 'xz')
_guideps=('gst-plugins-base' 'gtk3' 'librsvg' 'libgudev')
makedepends=('intltool' 'python' 'nasm' 'wget' 'cmake' 'meson'
"${_commondeps[@]}" "${_guideps[@]}")
source=(https://github.com/HandBrake/HandBrake/releases/download/$pkgver/HandBrake-$pkgver-source.tar.bz2)
sha256sums=('ec6feba97f426d545ec56cf1472eae5795d768bc1aec56c23bb76fc6b2ecf270')
build() {
cd "$srcdir/HandBrake-$pkgver"
./configure \
--prefix=/usr \
--enable-qsv \
--enable-fdk
make -C build
}
package_handbrake-fdkaac() {
pkgdesc="Multithreaded video transcoder"
conflicts=('handbrake')
depends=('desktop-file-utils' 'hicolor-icon-theme'
"${_commondeps[@]}" "${_guideps[@]}")
optdepends=('gst-plugins-good: for video previews'
'gst-libav: for video previews'
'libdvdcss: for decoding encrypted DVDs')
cd "$srcdir/HandBrake-$pkgver/build"
make DESTDIR="$pkgdir" install
rm "$pkgdir/usr/bin/HandBrakeCLI"
}
package_handbrake-cli-fdkaac() {
pkgdesc="Multithreaded video transcoder (CLI)"
conflicts=('handbrake-cli')
depends=("${_commondeps[@]}")
optdepends=('libdvdcss: for decoding encrypted DVDs')
cd "$srcdir/HandBrake-$pkgver/build"
install -D HandBrakeCLI "$pkgdir/usr/bin/HandBrakeCLI"
}
# vim:set ts=2 sw=2 et:
|