PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Josip Ponjavic <josipponjavic at gmail dot com>
# Contributor:

pkgname=haruna-git
pkgver=1.4.0.r60.g929a9ee6
pkgrel=1
pkgdesc='Video player built with Qt/QML on top of libmpv'
arch=(x86_64)
url='https://apps.kde.org/haruna/'
license=(GPL-3.0-or-later)
depends=(ffmpeg
         gcc-libs
         glibc
         kcolorscheme
         kconfig
         kcoreaddons
         kcrash
         kdeclarative
         kdsingleapplication
         kfilemetadata
         ki18n
         kio
         kirigami
         kwindowsystem
         mpvqt
         qqc2-desktop-style
         qt6-5compat
         qt6-base
         qt6-declarative)
makedepends=(extra-cmake-modules
             git
             kdoctools)
optdepends=('yt-dlp: YouTube support')
provides=("${pkgname%-*}")
conflicts=("${pkgname%-*}")
source=("${pkgname%-*}::git+https://invent.kde.org/multimedia/haruna.git")
sha256sums=('SKIP')

pkgver() {
  cd "${pkgname%-*}"
  git describe --long --tags | sed -r 's/([^-]*-g)/r\1/;s/-/./g;s/v//g'
}

build() {
  cmake -B build -S "${pkgname%-*}"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}