blob: efda09c5d64cb11b68fd5f9d4ce47a3324c67119 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: 71e6fd52 <71e6fd52 at gmail dot com>
_hkgname=brittany
pkgname=haskell-brittany
pkgver=0.12.1.1
pkgrel=1
pkgdesc="Haskell source code formatter (dynamic link)"
url='https://hackage.haskell.org/package/brittany'
license=('AGPL3')
arch=('x86_64')
depends=('ghc-libs' 'haskell-aeson' 'haskell-butcher' 'haskell-bytestring' 'haskell-cmdargs' 'haskell-containers' 'haskell-czipwith' 'haskell-data-tree-print' 'haskell-deepseq' 'haskell-directory' 'haskell-extra' 'haskell-filepath' 'haskell-ghc-boot-th' 'haskell-ghc-exactprint' 'haskell-ghc-paths' 'haskell-hspec' 'haskell-monad-memo' 'haskell-mtl' 'haskell-multistate' 'haskell-neat-interpolation' 'haskell-parsec' 'haskell-pretty' 'haskell-random' 'haskell-safe' 'haskell-semigroups' 'haskell-strict' 'haskell-syb' 'haskell-text' 'haskell-transformers' 'haskell-uniplate' 'haskell-unsafe' 'haskell-yaml')
makedepends=('ghc')
source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
sha512sums=('ac471ab778efd1a007e76594a54fe3bea8f96afc3f0714c7b0ec66273788a6c9d8e0d0b9d5e36c2a10d547d10a6ad2327ea540d836b9a12549a918b5c83a9425')
prepare() {
cd $_hkgname-$pkgver
sed -i -r 's/(neat-interpolation) .*$/\1/' $_hkgname.cabal
}
build() {
cd $_hkgname-$pkgver
runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
--prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
--dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
--ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
--ghc-option='-pie'
runhaskell Setup build
runhaskell Setup register --gen-script
runhaskell Setup unregister --gen-script
sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}
check() {
cd $_hkgname-$pkgver
runhaskell Setup test
}
package() {
cd $_hkgname-$pkgver
install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
runhaskell Setup copy --destdir="$pkgdir"
install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
|