blob: 3045a5472401114756e8736fbf6dad6902f4bb2e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Max <ulidtko@gmail.com>
_hkgname=extensions
pkgname=haskell-extensions
pkgver=0.0.0.1
pkgrel=1
pkgdesc="Parse Haskell Language Extensions"
url="https://github.com/kowainik/extensions"
license=("MPL2")
arch=('x86_64')
depends=('ghc-libs' 'haskell-colourista' 'haskell-optparse-applicative')
makedepends=(ghc haskell-hedgehog haskell-hspec haskell-hspec-hedgehog uusi)
source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz"
0001-Fix-overlapping-instances-error-on-GHC-9.0.2.patch
)
sha256sums=('d64cc9c0ea82ae8f2dbf0c08824f0a89d3e523105a235e788ef822ac779bb373'
'd7ed6ac8105bf36e23acc53a95e09b3a987b004b7f8f9b6f277f651fb73002ca')
prepare() {
cd "$_hkgname-$pkgver"
patch -p1 -i "$srcdir/0001-Fix-overlapping-instances-error-on-GHC-9.0.2.patch"
}
build() {
cd $_hkgname-$pkgver
gen-setup && uusi --all $_hkgname.cabal
runhaskell Setup configure -O \
--enable-shared --enable-executable-dynamic --disable-library-vanilla \
--prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
--dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
--ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
--ghc-option='-pie'
runhaskell Setup build
runhaskell Setup register --gen-script
runhaskell Setup unregister --gen-script
sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}
check() {
cd $_hkgname-$pkgver
runhaskell Setup test
}
package() {
cd $_hkgname-$pkgver
install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
runhaskell Setup copy --destdir="$pkgdir"
install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
|