blob: dec102fd2a6845b63baf1e7f72c600d220cf232a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Jaron Kent-Dobias <jaron@kent-dobias.com>
_hkgname=normaldistribution
pkgname=haskell-normaldistribution
pkgver=1.1.0.3
pkgrel=1
pkgdesc='Produces normally distributed random values with a minimum of fuss.'
url='https://hackage.haskell.org/package/normaldistribution'
license=('BSD-3')
arch=('x86_64')
depends=('ghc-libs' 'haskell-random')
makedepends=('ghc')
source=(https://hackage.haskell.org/package/${_hkgname}-${pkgver}/${_hkgname}-${pkgver}.tar.gz)
sha512sums=('7ec4cb82436fb48663dbbe3e2849d0597f242b72e8d211515451a81cb417e26c19708ea7854a93bcce0185408fd44431349f4ab9435ca49d04f4f3f9c6a3c063')
build() {
cd ${_hkgname}-${pkgver}
runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
--prefix=/usr --docdir=/usr/share/doc/$pkgname \
--dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
runhaskell Setup build
runhaskell Setup haddock
runhaskell Setup register --gen-script
runhaskell Setup unregister --gen-script
sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}
package() {
cd ${_hkgname}-${pkgver}
install -Dm 744 register.sh "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
install -Dm 744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
install -dm 755 "${pkgdir}/usr/share/doc/ghc/html/libraries"
runhaskell Setup copy --destdir="$pkgdir"
install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
install -Dm 644 README -t "${pkgdir}/usr/share/doc/${pkgname}"
ln -s /usr/share/doc/${pkgname}/html "${pkgdir}/usr/share/doc/ghc/html/libraries/${_hkgname}"
}
# vim: ts=2 sw=2 et:
|