PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: Daniel Nagy <danielnagy at gmx de>
# Contributor: Austin Robinson <austin.rbsn@gmail.com>

_hkgname=OpenGLRaw
pkgname=haskell-openglraw
pkgver=1.5.0.1
pkgrel=1
pkgdesc="A raw binding for the OpenGL graphics system"
url="http://hackage.haskell.org/package/${_hkgname}"
license=('custom:BSD3')
arch=('i686' 'x86_64')
makedepends=()
depends=('ghc' 'libgl')
options=('strip')
source=(http://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
install=${pkgname}.install
md5sums=('cfb842754fe17a2bdc16f0e155a6aced')

build() {
    cd "${srcdir}"/${_hkgname}-${pkgver}
    runhaskell Setup configure -O ${PKGBUILD_HASKELL_ENABLE_PROFILING:+-p } --enable-split-objs --enable-shared \
       --prefix=/usr --docdir=/usr/share/doc/${pkgname} --libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build
    runhaskell Setup haddock
    runhaskell Setup register   --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}
package() {
    cd "${srcdir}"/${_hkgname}-${pkgver}
    install -D -m744 register.sh   "${pkgdir}"/usr/share/haskell/${pkgname}/register.sh
    install    -m744 unregister.sh "${pkgdir}"/usr/share/haskell/${pkgname}/unregister.sh
    install -d -m755 "${pkgdir}"/usr/share/doc/ghc/html/libraries
    ln -s /usr/share/doc/${pkgname}/html ${pkgdir}/usr/share/doc/ghc/html/libraries/${_hkgname}
    runhaskell Setup copy --destdir="${pkgdir}"
    install -D -m644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
    rm -f "${pkgdir}"/usr/share/doc/${pkgname}/LICENSE
}