blob: 9ce9bb68a5ee46e0c009dfc88cb365fb1578fd52 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Leif Warner <abimelech@gmail.com>
# custom variables
_hkgname=time-units
pkgname=haskell-${_hkgname}
pkgver=1.0.0
pkgrel=1
license=(BSD-3-Clause)
pkgdesc="Basic library for type-described units of time."
url="http://hackage.haskell.org/package/${_hkgname}"
arch=('x86_64')
makedepends=("ghc")
depends=("haskell-base")
source=("http://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
sha256sums=('e181997dd05321f09b21c5e0bf38524ccab51ecc588a6017253cc96db289e099')
# PKGBUILD functions
build() {
cd "${srcdir}/${_hkgname}-${pkgver}"
runhaskell Setup configure -O --enable-executable-dynamic --disable-library-vanilla --enable-shared \
--prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" \
--libsubdir=\$compiler/site-local/\$pkgid --dynlibdir=/usr/lib
runhaskell Setup build
runhaskell Setup register --gen-script
runhaskell Setup unregister --gen-script
sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
}
package() {
cd "${srcdir}/${_hkgname}-${pkgver}"
install -D -m744 register.sh "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
runhaskell Setup copy --destdir="${pkgdir}"
install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
}
|