blob: f7169ef5a6eaf648f2bd8ac889ba223c775113af (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Leif Warner <abimelech@gmail.com>
# custom variables
_hkgname=xml-helpers
pkgname=haskell-${_hkgname}
pkgver=1.0.0
pkgrel=1
license=(BSD-3-Clause)
pkgdesc="Useful Haskell functions extending the xml library"
url="http://hackage.haskell.org/package/${_hkgname}"
arch=('x86_64')
makedepends=("ghc")
depends=("haskell-xml")
source=("http://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
sha256sums=('9b02c5bfd831e4e275745a3ca521a528a64ab0cf84022e17344873548f043367')
# PKGBUILD functions
build() {
cd "${srcdir}/${_hkgname}-${pkgver}"
runhaskell Setup configure -O --enable-executable-dynamic --disable-library-vanilla --enable-shared \
--prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" \
--libsubdir=\$compiler/site-local/\$pkgid --dynlibdir=/usr/lib
runhaskell Setup build
runhaskell Setup register --gen-script
runhaskell Setup unregister --gen-script
sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
}
package() {
cd "${srcdir}/${_hkgname}-${pkgver}"
install -D -m744 register.sh "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
runhaskell Setup copy --destdir="${pkgdir}"
install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
}
|