blob: 2f7a6f7f44e894ae2e8a86b7c305c489919dd56d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: acxz <akashpatel2008 at yahoo dot com>
_pkgname=hcc
pkgname="$_pkgname-git"
pkgver=latest
pkgrel=2
pkgdesc="C++ Compiler for Heterogeneous Compute"
arch=('x86_64')
url="https://github.com/RadeonOpenCompute/hcc"
license=('custom:NCSAOSL')
depends=('hsa-rocr')
makedepends=('git' 'cmake' 'python')
provides=('hcc')
conflicts=('hcc')
source=("git+https://github.com/RadeonOpenCompute/hcc.git"
"git+https://github.com/RadeonOpenCompute/llvm-project.git"
"git+https://github.com/RadeonOpenCompute/ROCm-Device-Libs.git")
sha256sums=('SKIP'
'SKIP'
'SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "$srcdir/$_pkgname"
git submodule init
git config submodule.llvm-project.url "$srcdir/llvm-project"
git config submodule.rocdl.url "$srcdir/ROCm-Device-Libs"
git submodule update
}
build() {
mkdir -p "$srcdir/build"
cd "$srcdir/build"
cmake -DCMAKE_INSTALL_PREFIX=/opt/rocm/hcc \
-DLLVM_INSTALL_UTILS=TRUE \
"$srcdir/$_pkgname"
make
}
package() {
cd "$srcdir/build"
make DESTDIR="$pkgdir" install
}
|