PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Maintainer: Jingbei Li <i@jingbei.li>

pkgname=hdf5_18-cpp-fortran
_pkgname=hdf5
pkgver=1.8.19
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc="General purpose library and file format for storing scientific data"
url="http://www.hdfgroup.org/HDF5/"
license=('custom')
depends=('zlib' 'sh' 'gcc-libs')
makedepends=('time' 'gcc-fortran')
provides=('hdf5_18')
conflicts=('hdf5_18')
source=("https://support.hdfgroup.org/ftp/HDF5/current18/src/${_pkgname}-${pkgver}.tar.bz2")
sha1sums=('4e950d3041c2afd6edd0cd739ed39080a8f1a4df')

build() {
	cd "$srcdir/${_pkgname}-${pkgver/_/-}"
	./configure --prefix=/usr --disable-static \
		--enable-hl \
		--enable-cxx \
		--enable-fortran \
		--enable-fortran2003 \
		--enable-linux-lfs \
		--enable-build-mode=production \
		--with-pic \
		--docdir=/usr/share/doc/hdf5_18/ \
		--with-pthread=/usr/lib \
		--disable-sharedlib-rpath \
		--libdir=/usr/lib/hdf5_18 \
		--includedir=/usr/include/hdf5_18
	make
}

package() {
	cd "$srcdir/${_pkgname}-${pkgver/_/-}"

	make -j1 DESTDIR="${pkgdir}" install

	rm -rf "${pkgdir}"/usr/share/hdf5_examples

	for file in "${pkgdir}"/usr/bin/*
	do
		mv "${file}" "${file}"_18
	done

	install -d m755 "${pkgdir}"/etc/ld.so.conf.d
	echo /usr/lib/hdf5_18 >> "${pkgdir}"/etc/ld.so.conf.d/hdf5_18.conf

	install -d -m755 "$pkgdir/usr/share/licenses/${pkgname}"
	install -m644 "$srcdir/${_pkgname}-${pkgver/_/-}/COPYING" \
		"$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
}