blob: 0e007070f117523fb87f0d68ad7d353a89230ac1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer : Grey Christoforo <first name at last name dot net>
pkgname=hdfview
_pkgname=HDFView
pkgver=3.3.1
pkgrel=1
pkgdesc="A visual tool for browsing and editing HDF4 and HDF5 files."
arch=('x86_64')
url="https://portal.hdfgroup.org/display/HDFVIEW/HDFView"
license=('custom')
depends=(hdf5 java-runtime)
makedepends=(ant gendesk hdf4 inetutils 'java-environment>=15')
optdepends=(hdf4)
source=("https://support.hdfgroup.org/ftp/HDF5/releases/HDF-JAVA/hdfview-${pkgver}/src/hdfview-${pkgver}.tar.gz")
sha256sums=('59c19871e30e07c802c9c2525b829d029cb68080604e713f7743f11990a552a8')
#check() {
# cd "${srcdir}/${pkgname}-${pkgver}"
#
# export HDFLIBS=/opt/hdf4
# export HDF5LIBS=/usr
# ant junit
#}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
export HDFLIBS=/opt/hdf4
export HDF5LIBS=/usr
ant createJPackage
gendesk -n --pkgname "$pkgname" --pkgdesc "$pkgdesc" --name ${_pkgname}
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
mkdir -p "${pkgdir}/opt/"
mkdir -p "${pkgdir}/usr/bin"
cp -a build/dist/${_pkgname} "${pkgdir}/opt/${pkgname}"
ln -s /opt/${pkgname}/bin/${_pkgname} "${pkgdir}/usr/bin/${pkgname}"
install -Dm644 "$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"
install -Dm644 "src/HDFView.png" "$pkgdir/usr/share/pixmaps/$pkgname.png"
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|