blob: 4f29a9e17f9909e8bc60c7b12c9379ce3960991a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=hdrhistogram_c-git
pkgver=0.11.8.r4.ge33c19c
pkgrel=1
pkgdesc="C port of the HdrHistogram"
arch=('i686' 'x86_64')
url="https://hdrhistogram.github.io/HdrHistogram/"
license=('BSD-2-Clause' 'CC0-1.0')
depends=('glibc' 'zlib')
makedepends=('git' 'cmake')
provides=("hdrhistogram_c=$pkgver")
conflicts=('hdrhistogram_c')
options=('staticlibs')
source=("git+https://github.com/HdrHistogram/HdrHistogram_c.git")
sha256sums=('SKIP')
pkgver() {
cd "HdrHistogram_c"
_tag=$(git tag -l --sort -creatordate | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^HdrHistogram_c-//'
}
build() {
cd "HdrHistogram_c"
CFLAGS="$CFLAGS -ffat-lto-objects" \
CXXFLAGS="$CXXFLAGS -ffat-lto-objects" \
cmake \
-B "_build" \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DCMAKE_INSTALL_LIBDIR="lib" \
./
make -C "_build"
}
check() {
cd "HdrHistogram_c"
#make -C "_build" test
}
package() {
cd "HdrHistogram_c"
make -C "_build" DESTDIR="$pkgdir" install
install -Dm644 {COPYING,LICENSE}.txt -t "$pkgdir/usr/share/licenses/hdrhistogram_c"
}
|