PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

# Maintainer: Arvid Norlander <VorpalBlade@users.noreply.github.com>
# Contributor: Lukas Jirkovsky <l.jirkovsky@gmail.com>
pkgname=heaptrack-git
_pkgname=heaptrack
pkgver=1543.c8ed4c5
pkgrel=1
pkgdesc="A heap memory profiler"
arch=('x86_64')
url="https://apps.kde.org/heaptrack/"
license=('LGPL-2.1-or-later')
depends=(boost-libs
         gcc-libs
         glibc
         hicolor-icon-theme
         kcolorscheme
         kconfig
         kconfigwidgets
         kcoreaddons
         kdiagram
         ki18n
         kiconthemes
         kio
         kwidgetsaddons
         libelf
         libunwind
         qt6-base
         qt6-svg
         rustc-demangle
         sh
         threadweaver
         zstd
)
makedepends=(boost
             extra-cmake-modules
             git
             kitemmodels
             ninja
)
provides=('heaptrack')
conflicts=('heaptrack')
source=('heaptrack::git+https://invent.kde.org/sdk/heaptrack.git')
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/heaptrack"
  echo $(git rev-list --count master).$(git rev-parse --short master)
}

prepare() {
  mkdir -p "$srcdir/build"
}

build() {
  cmake -B build -S $_pkgname \
   -G Ninja \
   -DCMAKE_INSTALL_PREFIX=/usr \
   -DBUILD_TESTING=OFF \
   -DHEAPTRACK_USE_QT6=ON \
   -DCMAKE_BUILD_TYPE=Release \
   -DCMAKE_POLICY_VERSION_MINIMUM=3.5
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}