blob: fc6e5774d7f00ed07b9df747d14ddbd3708123df (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: ml <ml@visu.li>
pkgname=helm-diff
pkgver=3.4.0
pkgrel=1
pkgdesc='Helm plugin that shows a diff explaining what a helm upgrade would change'
arch=('x86_64')
url='https://github.com/databus23/helm-diff'
license=('Apache')
install=helm-diff.install
depends=('helm')
makedepends=('go')
source=("$url/archive/v$pkgver/$pkgname-$pkgver.tar.gz")
sha256sums=('f7d9ea36dfdce6c41c841f3607d415232ab5e6c4f0aff1844462abacec0a2291')
prepare() {
sed -i '/^hooks:$/Q' "$pkgname-$pkgver"/plugin.yaml
}
build() {
cd "$pkgname-$pkgver"
export CGO_ENABLED=1
export CGO_LDFLAGS="$LDFLAGS"
export CGO_CFLAGS="$CFLAGS"
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export GOFLAGS='-buildmode=pie -modcacherw -trimpath'
go build -o bin/diff -ldflags "-linkmode=external -X github.com/databus23/helm-diff/cmd.Version=$pkgver" main.go
}
check() {
cd "$pkgname-$pkgver"
go test -ldflags "-linkmode=external" ./...
}
package() {
cd "$pkgname-$pkgver"
# /usr/lib/helm/plugins is my own choice and not a standard. feedback welcome
install -Dm755 bin/diff -t "$pkgdir/usr/lib/helm/plugins/${pkgname##helm-}/bin"
install -m644 plugin.yaml -t "$pkgdir/usr/lib/helm/plugins/${pkgname##helm-}"
}
|