blob: 04c6e3d05e824d6986d0d4393e414d5e9be6306f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>
_pkgname=helm
pkgname="${_pkgname}-git"
pkgver=0.9.0.r1897.abdedd52
pkgrel=1
pkgdesc="a cross-platform, polyphonic synthesizer LV2 and VST plugin"
arch=('i686' 'x86_64')
url="http://tytel.org/helm/"
license=('GPL')
groups=('lv2-plugins' 'vst-plugins')
depends=('alsa-lib' 'curl' 'freetype2' 'hicolor-icon-theme' 'mesa' 'libxinerama' 'lv2')
makedepends=('git')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("${_pkgname}::git+https://github.com/mtytel/helm.git")
md5sums=('SKIP')
changelog=ChangeLog
pkgver() {
cd "${srcdir}/${_pkgname}"
ver="$(grep 'JUCERPROJECT.*version' helm.jucer | sed 's/.*version=\"\(.*\)\".*/\1/')"
echo "${ver}.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
build() {
cd "${srcdir}/${_pkgname}"
make CONFIG=Release PREFIX="/usr" all vst
}
package() {
cd "${srcdir}/${_pkgname}"
make CONFIG=Release PREFIX="/usr" DESTDIR="$pkgdir" install
install -D builds/linux/VST/build/helm.so "$pkgdir/usr/lib/vst/helm.so"
}
|