blob: ac6eeecd822ba24144e73095912b1ade82dd711c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Brian Bidulock <bidulock@openss7.org>
# Contributor: Jonathan Steel <jsteel at archlinux.org>
# Contributor: thorsten w. <p@thorsten-wissmann.de>
pkgname=herbstluftwm-git
_pkgname=herbstluftwm
pkgver=0.9.3.r23.g9cdf6938
pkgrel=1
epoch=1
pkgdesc="Manual tiling window manager for X"
arch=('x86_64' 'i686')
url="https://herbstluftwm.org"
license=('BSD')
depends=('bash' 'libxinerama' 'libxrandr' 'libxft')
makedepends=('git' 'cmake' 'asciidoc')
optdepends=('xorg-xsetroot: to set wallpaper color in default autostart'
'xterm: used as the terminal in default autostart'
'dzen2: used in the default panel.sh'
'dmenu: used in some example scripts')
source=("$pkgname::git://github.com/herbstluftwm/$_pkgname")
sha256sums=('SKIP')
validpgpkeys=('72B6C05CDFF309C6396167D464EF02821CAFF810') # Thorsten Wißmann <edu@thorsten-wissmann.de>
provides=($_pkgname)
conflicts=($_pkgname)
pkgver() {
cd ${pkgname}
git describe --tags --long | sed -r 's,^[^0-9]*,,;s,([^-]*-g),r\1,;s,[-_],.,g'
}
build() {
cd $pkgname
mkdir -p build; cd build
cmake \
-DBASHCOMPLETIONDIR=/usr/share/bash-completion/completions \
-DZSHCOMPLETIONDIR=/usr/share/zsh/functions/Completion/X \
-DCMAKE_INSTALL_PREFIX="/usr" ..
make
}
package() {
cd $pkgname/build
make DESTDIR="$pkgdir" install
install -d "$pkgdir"/usr/share/licenses/$pkgname/
ln -s /usr/share/doc/$_pkgname/LICENSE \
"$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
|