blob: 7f1d5b4e8a01decfd38642823621a5005afebfec (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: thorsten w. <p@thorsten-wissmann.de>
# Maintainer: Florian Bruhin (The Compiler) <archlinux.org@the-compiler.org>
pkgname=herbstluftwm-git
_pkgname=herbstluftwm
pkgver=0.8.0.r14.g3387014f
pkgrel=1
pkgdesc="Manual tiling window manager for X"
arch=('i686' 'x86_64')
url="http://herbstluftwm.org"
license=('BSD')
depends=('libx11' 'libxinerama')
optdepends=(
'bash: needed by most scripts'
'xterm: used by the default autostart'
'dmenu: needed by some scripts'
'dzen2: needed by panel.sh'
'dzen2-xft-xpm-xinerama-git: view icons as tags'
)
makedepends=('git' 'asciidoc' 'cmake')
provides=($_pkgname)
conflicts=($_pkgname)
source=("$_pkgname::git://github.com/herbstluftwm/$_pkgname")
md5sums=( SKIP )
pkgver() {
cd $_pkgname
git describe --tags --long | sed -r 's,^[^0-9]*,,;s,([^-]*-g),r\1,;s,[-_],.,g'
}
prepare() {
rm -r build || true
mkdir build
}
build() {
cd build
cmake -DCMAKE_INSTALL_PREFIX=/usr ../$_pkgname
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
cd "$srcdir/$_pkgname"
install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
}
|