blob: 0ff9d67f4a084be4f9509cf2a1621bd9dfd05a3d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: TingPing tingping@tingping.se
pkgname=hexchat-git
pkgver=2.12.0.r1266.gb7373f4
pkgrel=1
pkgdesc='A GTK+ based IRC client'
arch=('i686' 'x86_64' 'armv6h')
url='https://hexchat.github.io'
license=('GPL')
options=('!libtool')
depends=('gtk2' 'openssl' 'dbus-glib'
'libcanberra' 'libnotify' 'libproxy'
'hicolor-icon-theme' 'desktop-file-utils' 'sound-theme-freedesktop' 'iso-codes')
makedepends=('intltool' 'git' 'perl' 'python' 'autoconf-archive')
optdepends=('enchant: for spell check'
'perl: for perl plugin'
'python: for python plugin')
install='hexchat.install'
provides=('hexchat')
conflicts=('hexchat')
source=('git://github.com/hexchat/hexchat.git')
md5sums=('SKIP')
_gitname='hexchat'
prepare() {
cd "$_gitname"
# Needed for pkgver()
aclocal
}
pkgver() {
cd "$_gitname"
# Development releases don't get tags, so pull it from configure.ac
_ver=`autoconf -t 'AC_INIT:$2'`
_rev=`git describe | sed 's/^v[^-]*-/r/; s/-/./'`
echo "$_ver.$_rev"
}
build() {
cd "$srcdir/$_gitname"
./autogen.sh --prefix=/usr --enable-textfe --enable-python=python3 --disable-debug
make -s
}
package() {
cd "$srcdir/$_gitname"
make DESTDIR="$pkgdir" install
}
|