blob: 4950ff27b116b84b5e5da4abbb45335a9d49e756 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Fabio 'Lolix' Loli <lolix@disroot.org> -> https://github.com/FabioLolix
# Contributor: Salvador PardiƱas <darkfm@vera.com.uy>
pkgname=higan-git
pkgver=106.r221.g327a19dc
pkgrel=1
pkgdesc="Nintendo multi-system emulator by Byuu"
arch=(x86_64 i686)
url="https://byuu.org"
license=(GPL3)
depends=(libpulse gtksourceview2 sdl2 libxv libao libgl openal)
makedepends=(git mesa)
provides=(higan)
conflicts=(higan)
source=("git+https://gitlab.com/higan/higan.git")
sha256sums=('SKIP')
pkgver() {
cd higan
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd higan
make -C higan target=higan
make -C icarus
}
package() {
cd higan
install -Dm 755 higan/out/higan -t "${pkgdir}"/usr/bin/
install -Dm 644 higan/target-higan/resource/higan.desktop -t "${pkgdir}"/usr/share/applications/
install -Dm 644 higan/target-higan/resource/higan.png -t "${pkgdir}"/usr/share/pixmaps/
cp -dr --no-preserve='ownership' higan/System "${pkgdir}"/usr/share/higan
install -Dm 755 icarus/out/icarus -t "${pkgdir}"/usr/bin/
install -Dm 644 icarus/data/icarus.desktop -t "${pkgdir}"/usr/share/applications/
install -Dm 644 icarus/data/icarus.png -t "${pkgdir}"/usr/share/pixmaps/
install -dm 755 "${pkgdir}"/usr/share/icarus
cp -dr --no-preserve='ownership' icarus/Database "${pkgdir}"/usr/share/icarus/
install -dm 644 "${pkgdir}"/usr/share/higan/Video\ Shaders
cp -dr --no-preserve='ownership' shaders/*.shader "${pkgdir}"/usr/share/higan/Video\ Shaders
}
|