blob: 8e2b7b95f9da7ae87c5ade2920f8210b7b5a90ab (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: acxz <akashpatel2008 at yahoo dot com>
pkgname=hip-rocclr
pkgver=4.0.0
pkgrel=2
pkgdesc="Heterogeneous Interface for Portability ROCm"
arch=('x86_64')
url='https://rocmdocs.amd.com/en/latest/Installation_Guide/HIP.html'
license=('MIT')
depends=('rocclr' 'rocminfo' 'libelf')
makedepends=('cmake' 'python' 'git')
provides=('hip')
conflicts=('hip')
_git='https://github.com/ROCm-Developer-Tools/HIP'
source=("$pkgname-$pkgver.tar.gz::$_git/archive/rocm-$pkgver.tar.gz"
'amdgpu-targets.patch')
sha256sums=('d7b78d96cec67c55b74ea3811ce861b16d300410bc687d0629e82392e8d7c857'
'c6358b4dfac658c0a27a3425ace455d951cd26be827dd7751c28cb83dc84b67d')
_dirname="$(basename "$_git")-$(basename "${source[0]}" ".tar.gz")"
prepare() {
cd "$_dirname"
patch -Np1 -i "$srcdir/amdgpu-targets.patch"
}
build() {
CXXFLAGS="$CXXFLAGS -isystem /opt/rocm/rocclr/include/compiler/lib/include -isystem /opt/rocm/rocclr/include/elf" \
cmake -B build -Wno-dev \
-S "$_dirname" \
-DCMAKE_INSTALL_PREFIX=/opt/rocm/hip \
-DCMAKE_PREFIX_PATH='/opt/rocm/lib/cmake/hsa-runtime64;/opt/rocm/lib/cmake/amd_comgr' \
-DHIP_COMPILER=clang \
-DHIP_PLATFORM=rocclr \
-D__HIP_ENABLE_PCH=OFF
make -C build
}
package() {
DESTDIR="$pkgdir" make -C build install
# clang from llvm-amdgpu may look for hipVersion in a different directory
install -d "$pkgdir/opt/rocm/bin"
ln -s '/opt/rocm/hip/bin/.hipVersion' "$pkgdir/opt/rocm/bin/.hipVersion"
# add links (hipconfig is for rocblas with tensile)
install -d "$pkgdir/usr/bin"
local _fn
for _fn in hipcc hipconfig; do
ln -s "/opt/rocm/hip/bin/$_fn" "$pkgdir/usr/bin/$_fn"
done
# Some packages search for hip includes in /opt/rocm/include/hip
install -d "$pkgdir/opt/rocm/include"
ln -s "/opt/rocm/hip/include/hip" "$pkgdir/opt/rocm/include/hip"
install -Dm644 /dev/stdin "$pkgdir/etc/ld.so.conf.d/hip.conf" <<EOF
/opt/rocm/hip/lib
EOF
install -Dm644 "$srcdir/HIP-rocm-$pkgver/LICENSE.txt" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|