blob: a062be99f656195d9bb7989c0d08065394ac8e67 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Torsten Keßler <t dot kessler at posteo dot de>
# Contributor: acxz <akashpatel2008 at yahoo dot com>
pkgname=hip-rocclr
pkgver=4.3.0
pkgrel=1
pkgdesc="Heterogeneous Interface for Portability ROCm"
arch=('x86_64')
url='https://rocmdocs.amd.com/en/latest/Installation_Guide/HIP.html'
license=('MIT')
depends=('rocclr' 'rocminfo' 'libelf')
makedepends=('cmake' 'python' 'git')
provides=('hip')
conflicts=('hip')
_git='https://github.com/ROCm-Developer-Tools/HIP'
_roctracer='https://github.com/ROCm-Developer-Tools/roctracer'
_opencl='https://github.com/RadeonOpenCompute/ROCm-OpenCL-Runtime'
source=("$pkgname-$pkgver.tar.gz::$_git/archive/rocm-$pkgver.tar.gz"
"$pkgname-roctracer-$pkgver.tar.gz::$_roctracer/archive/rocm-$pkgver.tar.gz"
"$pkgname-opencl-$pkgver.tar.gz::$_opencl/archive/rocm-$pkgver.tar.gz")
sha256sums=('293b5025b5e153f2f25e465a2e0006a2b4606db7b7ec2ae449f8a4c0b52d491b'
'c3d9f408df8d4dc0e9c0026217b8c684f68e775da80b215fecb3cd24419ee6d3'
'd37bddcc6835b6c0fecdf4d02c204ac1d312076f3eef2b1faded1c4c1bc651e9')
_dirname="$(basename "$_git")-$(basename "${source[0]}" ".tar.gz")"
_dirtracer="$(basename "$_roctracer")-$(basename "${source[1]}" ".tar.gz")"
build() {
CXXFLAGS="$CXXFLAGS -isystem /opt/rocm/include/compiler/lib/include -isystem /opt/rocm/include/elf -isystem $srcdir/ROCm-OpenCL-Runtime-rocm-$pkgver" \
cmake -B build -Wno-dev \
-S "$_dirname" \
-DCMAKE_INSTALL_PREFIX=/opt/rocm/hip \
-DCMAKE_PREFIX_PATH=/opt/rocm/lib/cmake \
-DPROF_API_HEADER_PATH="$srcdir/$_dirtracer/inc/ext" \
-DCMAKE_HIP_ARCHITECTURES='gfx900;gfx906;gfx908' \
-DHIP_COMPILER=clang \
-DHIP_PLATFORM=rocclr \
-D__HIP_ENABLE_PCH=OFF
make -C build
}
package() {
DESTDIR="$pkgdir" make -C build install
# add links (hipconfig is for rocblas with tensile)
install -d "$pkgdir/usr/bin"
install -d "$pkgdir/opt/rocm/bin"
local _fn
for _fn in hipcc hipconfig; do
ln -s "/opt/rocm/hip/bin/$_fn" "$pkgdir/usr/bin/$_fn"
ln -s "/opt/rocm/hip/bin/$_fn" "$pkgdir/opt/rocm/bin/$_fn"
done
# clang from llvm-amdgpu may look for hipVersion in a different directory
ln -s '/opt/rocm/hip/bin/.hipVersion' "$pkgdir/opt/rocm/bin/.hipVersion"
# Some packages search for hip includes in /opt/rocm/include
install -d "$pkgdir/opt/rocm/include"
ln -s "/opt/rocm/hip/include/hip" "$pkgdir/opt/rocm/include/hip"
# Same holds for the HIP library
install -d "$pkgdir/opt/rocm/lib"
ln -s "/opt/rocm/hip/lib/libamdhip64.so" "$pkgdir/opt/rocm/lib/libamdhip64.so"
# CMake projects with language "HIP" look for hip config files in /opt/rocm/lib
install -d "$pkgdir/opt/rocm/lib/cmake"
ln -s "/opt/rocm/hip/lib/cmake/hip" "$pkgdir/opt/rocm/lib/cmake/hip"
ln -s "/opt/rocm/hip/lib/cmake/hip-lang" "$pkgdir/opt/rocm/lib/cmake/hip-lang"
install -Dm644 /dev/stdin "$pkgdir/etc/ld.so.conf.d/hip.conf" <<EOF
/opt/rocm/hip/lib
EOF
install -Dm644 "$srcdir/HIP-rocm-$pkgver/LICENSE.txt" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|